3


0

UNIX tarおよびgrepループの支援

私のファイル拡張子.tar.gzの1つを解凍し、それを解凍し、grep -a >> output.textを使用して内部のファイル(拡張子.tlg)を検索するループを作成するのに助けが必要です。

outout.textでは、一致するデータと、ファイルの名前およびそれが由来する親tarが必要です。

この検索が実行された後、すべてのtarがチェックされるまで、untarされたファイルを削除し、次のtarファイルで続行することを希望します。

私はこれのためのディスクスペースを持っていないので、私は一度にすべてを解凍することはできません

誰も手伝ってくれる?

ありがとう

2 Answer


0


tarをループして抽出し、grepすることができます。このような何かが動作するはずです:

match="somestring"
mkdir out/
for i in *.tar.gz; do
 mkdir out/${i} # create outdir
 tar -C out/${i} -xf ${i} # extract to sub-dir with same name as tar;
                          # this will show up in grep output
 cd out
 grep -r ${match} ${i} >> ../output.text
 cd ..
 rm -rf out/${i} # delete untarred files
done

$ i変数の内容はrm -rfに渡され、内容を完全に削除することができるため、注意してください。


0


一時ファイルを作成しないようにするには、GNU tarのhttp://www.gnu.org/software/tar/manual/html_node/Option-Summary.html#IDX167 [--to-stdout]オプションを使用できます。

以下のコードは、シェルを混乱させる可能性のあるパス内のスペースやその他の文字に注意しています。

#! /usr/bin/perl

use warnings;
use strict;

sub usage { "Usage: $0 pattern tar-gz-file ..\n" }

sub output_from {
  my($cmd,@args) = @_;
  my $pid = open my $fh, "-|";
  warn("$0: fork: $!"), return unless defined $pid;
  if ($pid) {
    my @lines = <$fh>;
    close $fh or warn "$0: $cmd @args exited " . ($? >> 8);
    wantarray ? @lines : join "" => @lines;
  }
  else {
    exec $cmd, @args or die "$0: exec $cmd @args: $!\n";
  }
}

die usage unless @ARGV >= 2;
my $pattern = shift;
foreach my $tgz (@ARGV) {
  chomp(my @toc = output_from "tar", "-ztf", $tgz);
  foreach my $tlg (grep /\.tlg\z/, @toc) {
    my $line = 0;
    for (output_from "tar", "--to-stdout", "-zxf", $tgz, $tlg) {
      ++$line;
      print "$tlg:$line: $_" if /$pattern/o;
    }
  }
}

サンプル実行:

$ ./grep-tlgs hello tlgs.tar.gz
tlgs/another.tlg:2: hello
tlgs/file1.tlg:2: hello
tlgs/file1.tlg:3: hello
tlgs/third.tlg:1: hello
$ ./grep-tlgs ^ tlgs.tar.gz
tlgs/another.tlg:1: blah blah
tlgs/another.tlg:2: hello
tlgs/another.tlg:3: howdy
tlgs/file1.tlg:1: whoah
tlgs/file1.tlg:2: hello
tlgs/file1.tlg:3: hello
tlgs/file1.tlg:4: good-bye
tlgs/third.tlg:1: hello
tlgs/third.tlg:2: howdy
$ ./grep-tlgs ^ xtlgs.tar.gz
tar: xtlgs.tar.gz: Cannot open: No such file or directory
tar: Error is not recoverable: exiting now
tar: Child returned status 2
tar: Exiting with failure status due to previous errors
./grep-tlgs: tar -ztf xtlgs.tar.gz exited 2 at ./grep-tlgs line 14.